Digest::MD53pm

Usage

 # Functional style
 use Digest::MD5  qw(md5 md5_hex md5_base64);

 $digest = md5($data);
 $digest = md5_hex($data);
 $digest = md5_base64($data);

 # OO style
 use Digest::MD5;

 $ctx = Digest::MD5->new;

 $ctx->add($data);
 $ctx->addfile(*FILE);

 $digest = $ctx->digest;
 $digest = $ctx->hexdigest;
 $digest = $ctx->b64digest;

Overview

The `Digest::MD5' module allows you to use the RSA Data Security Inc. MD5 Message Digest algorithm from within Perl programs. The algorithm takes as input a message of arbitrary length and produces as output a 128-bit "fingerprint" or "message digest" of the input.

The `Digest::MD5' module provide a procedural interface for simple use, as well as an object oriented interface that can handle messages of arbitrary length and which can read files directly.

A binary digest will be 16 bytes long. A hex digest will be 32 characters long. A base64 digest will be 22 characters long.

Functions

The following functions can be exported from the `Digest::MD5' module. No functions are exported by default.

md5($data,...)

This function will concatenate all arguments, calculate the MD5 digest of this "message", and return it in binary form.

md5_hex($data,...)

Same as md5(), but will return the digest in hexadecimal form.

md5_base64($data,...)

Same as md5(), but will return the digest as a base64 encoded string.

Methods

The following methods are available:

$md5 = Digest::MD5->new

The constructor returns a new `Digest::MD5' object which encapsulate the state of the MD5 message-digest algorithm. You can add data to the object and finally ask for the digest.

If called as a instance method (i.e. $md5->new) it will just reset the state the object to the state of a newly created object. No new object is created in this case.

$md5->reset

This is just an alias for $md5->new.

$md5->add($data,...)

The $data provided as argument are appended to the message we calculate the digest for. The return value is the $md5 object itself.

$md5->addfile($io_handle)

The $io_handle is read until EOF and the content is appended to the message we calculate the digest for. The return value is the $md5 object itself.

In most cases you want to make sure that the $io_handle is set up to be in binmode().

$md5->digest

Return the binary digest for the message.

Note that the `digest' operation is effectively a destructive, read-once operation. Once it has been performed, the `Digest::MD5' object is automatically `reset' and can be used to calculate another digest value.

$md5->hexdigest

Same as $md5->digest, but will return the digest in hexadecimal form.

$md5->b64digest

Same as $md5->digest, but will return the digest as a base64 encoded string.

Examples

The simplest way to use this library is to import the md5_hex() function (or one of its cousins):

    use Digest::MD5 qw(md5_hex);
    print "Digest is ", md5_hex("foobarbaz"), "\n";

The above example would print out the message

    Digest is 6df23dc03f9b54cc38a0fc1483df6e21

provided that the implementation is working correctly. The same checksum can also be calculated in OO style:

    use Digest::MD5;

    $md5 = Digest::MD5->new;
    $md5->add('foo', 'bar');
    $md5->add('baz');
    $digest = $md5->hexdigest;

    print "Digest is $digest\n";

With OO style you can break the message arbitrary. This means that we are no longer limited to have space for the whole message in memory, i.e. we can handle messages of any size.

This is useful when calculating checksum for files:

    use Digest::MD5;

    my $file = shift ⎪⎪ "/etc/passwd";
    open(FILE, $file) or die "Can't open '$file': $!";
    binmode(FILE);

    $md5 = Digest::MD5->new;
    while (<FILE>) {
        $md5->add($_);
    }
    close(FILE);
    print $md5->b64digest, " $file\n";

Or we can use the builtin addfile method for more efficient reading of the file:

    use Digest::MD5;

    my $file = shift ⎪⎪ "/etc/passwd";
    open(FILE, $file) or die "Can't open '$file': $!";
    binmode(FILE);

    print Digest::MD5->new->addfile(*FILE)->hexdigest, " $file\n";