Sub::HandlesVia::Manual::WithCorinna(3pm)

Usage

 use v5.038;
 use experimental 'class';
 
 class Kitchen {
   field $foods :param = [];
   method foods () { return $foods }
   method _set_foods ($new) { $foods = $new }
   use Sub::HandlesVia::Declare [ 'foods', '_set_foods', sub { [] } ],
     Array => (
       all_foods => 'all',
       add_food  => 'push',
       eat_all   => 'reset',
     );
 }
 
 my $kitchen = Kitchen->new;
 $kitchen->add_food( 'apples' );
 $kitchen->add_food( 'carrots' );
 
 say "I have:";
 say "- $_" for $kitchen->all_foods;
 
 say "Now I will eat them all!";
 $kitchen->eat_all;

Manual

Sub::HandlesVia allows you to delegate methods from your class to the values of your objects' attributes.

Conceptually, it allows you to define "$object->push_number($n)" to be a shortcut for "$object->numbers->push($n)" except that "$object->numbers" is an arrayref, so doesn't have methods you can call on it like "push".

Sub::HandlesVia provides support for the Perl 5.38+ "class" keyword via Sub::HandlesVia::Declare.

As of the current version, you need to provide a "getter" and "setter" method to allow Sub::HandlesVia to access the attribute's value. It's also recommended to provide a coderef that Sub::HandlesVia can use to "reset" the value.

Which Methods Can Be Delegated To?

The second parameter ("Array" in the synopsis) indicates which library of methods should be available. Valid values include Array, Blessed, Bool, Code, Counter, Enum, Hash, Number, Scalar, and String.

An arrayref can be provided, though many of the options are conceptually contradictory.

 use Sub::HandlesVia::Declare 'num', [ 'Number', 'Scalar' ] => (
   ...,
 );

Copyright and licence

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

Disclaimer of warranties

THIS PACKAGE IS PROVIDED "AS IS" AND WITHOUT ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF MERCHANTIBILITY AND FITNESS FOR A PARTICULAR PURPOSE.