MooseX::Role::Parameterized3pm

Usage

    package Counter;
    use MooseX::Role::Parameterized;
    parameter name => (
        isa      => 'Str',
        required => 1,
    );
    role {
        my $p = shift;
        my $name = $p->name;
        has $name => (
            is      => 'rw',
            isa     => 'Int',
            default => 0,
        );
        method "increment_$name" => sub {
            my $self = shift;
            $self->$name($self->$name + 1);
        };
        method "reset_$name" => sub {
            my $self = shift;
            $self->$name(0);
        };
    };
    package MyGame::Weapon;
    use Moose;
    with Counter => { name => 'enchantment' };
    package MyGame::Wand;
    use Moose;
    with Counter => { name => 'zapped' };

Version

version 1.11

Overview

Your parameterized role consists of two new things: parameter declarations and a "role" block.

Parameters are declared using the "parameter" keyword which very much resembles "has" in Moose. You can use any option that "has" in Moose accepts. The default value for the "is" option is "ro" as that's a very common case. Use "is => 'bare'" if you want no accessor. These parameters will get their values when the consuming class (or role) uses "with" in Moose. A parameter object will be constructed with these values, and passed to the "role" block.

The "role" block then uses the usual Moose::Role keywords to build up a role. You can shift off the parameter object to inspect what the consuming class provided as parameters. You use the parameters to customize your role however you wish.

There are many possible implementations for parameterized roles (hopefully with a consistent enough API); I believe this to be the easiest and most flexible design. Coincidentally, Pugs originally had an eerily similar design.

See MooseX::Role::Parameterized::Extending for some tips on how to extend this module.

MooseX::Role::Parameterized::Tutorial

Stop! If you're new here, please read MooseX::Role::Parameterized::Tutorial for a much gentler introduction.

You also get the usual introspective and intercessory abilities that come standard with the metaobject protocol. Ambitious users should be able to add traits to the parameters metaclass to further customize behavior. Please let me know if you're doing anything viciously complicated with this extension. :)

Caveats

You must use this syntax to declare methods in the role block: "method NAME => sub { ... };". This is due to a limitation in Perl. In return though you can use parameters in your methods!

Support

Bugs may be submitted through the RT bug tracker <https://rt.cpan.org/Public/Dist/Display.html?Name=MooseX-Role-Parameterized> (or [email protected] <mailto:[email protected]>).

There is also a mailing list available for users of this distribution, at <http://lists.perl.org/list/moose.html>.

There is also an irc channel available for users of this distribution, at "#moose" on "irc.perl.org" <irc://irc.perl.org/#moose>.

Contributors

Copyright and license

This software is copyright (c) 2008 by Shawn M Moore.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.